Virtual Vibrations/Virtual Vibrations.iso/pc/install.dat

INSTALL Professional project | 1994-10-03 | 13.7 KB | 360 lines

/*
 INSTALL.DAT

 Project: Starware CD-ROM Sampler
 Version: 1.0

*/

/*  The @DefineProject block starts the installation script by telling
    Install what version, product, and other basic information that
    Install will need to process the installation.  The text that
    @Name is set to is the same information that can be found on the
    first line of the DISK.ID file.  Likewise the text that @Version
    is set to, is the same information that can be found on the second
    line of the DISK.ID file.  This information remains constant
    throughout the entire distribution set.  @Subdir and @OutDrive are
    used to define the default drive and directory for the target system
    during the installation process.  @InDiskBell set to @True will cause
    INSTALL to beep when it prompts the user for additional disks during
    the installation.
*/

@DefineProject
    @Name = "Starware CD-ROM Sampler"
    @Version = "1.0"
    @SubDir = "\\Starware\\sampler" //Line 26
    @OutDrive = C

@EndProject

/*  The following @DefineVars block is used to assign variables to
    specific types (Integer, QString, Drive, & Dir) as well as establishing
    default values for the variables.  Variables may be used throughout
    the wINSTALL script file, and can be assigned to any legal value for
    its type, at just about any time during the script file.  Later in
    this script file these variables are assigned values depending whether
    particular files will be installed or not.
*/

@DefineVars
    @Integer @samp       = 930
    @Integer @qtw       = 1408
    @Integer @TSIZE      = @Eval(@samp+@qtw)
    @Integer @Red        = @RGB(255,0,0)             //DEFINE COLOR RED
    @Integer @Green      = @RGB(0,255,0)             //DEFINE COLOR GREEN
    @Integer @Blue       = @RGB(0,0,255)             //DEFINE COLOR BLUE
    @Integer @Black      = @RGB(0,0,0)               //DEFINE COLOR BLACK
    @Drive @QTWDrive = C
    @Dir @QTWDirectory = "\\QTW\\BIN"
    @Drive @SampleDrive = C
    @Dir @SampleDirectory = "\\Starware\\Sampler"
    @Qstring @CDLetter = "@StartupDrive"
@EndVars

//@BackgroundMode(3,@Blue,@Black)
@BackgroundMode(1,0,0)
/*
    The following section displays the welcoming message during installation.
    @MoveCStr is essentially the same as the @MoveStr command, except that
    it allows you to change the background and foreground colors at the
    specified location. (Note MoveCStr() is only valid under DOS installations.)
*/


@Display
@Cls
This program installs the Starware CD-ROM Sampler
on your hard drive.  To continue, choose "OK".  To quit choose
"Cancel".
@Pause
@Enddisplay

@SetOption(1001)
@SetOption(1002)

LOOP:
@BackgroundMode(1,0,0)


@DlgCtrlSize(0,7,5,14,50)  // set coordinates & size of list box
@GetGroups
    @Checkbox
    Select Programs to install:

    @Set S = "Install The Starware CD-ROM Sampler"
    @Set Q = "Install Quicktime for Windows 1.1"
    @SetGroup(S)
    @SetGroup(Q)
@EndGroups
@If('S' [! @Group)
    @If('Q' [! @Group)
        @Display
        You have not selected any programs to install.

        @Abort
        @EndDisplay
    @EndIf
@EndIf
@If ('S' [= @Group)
NEWDRIVE:  // Goto label for reselecting drive
/*
    wINSTALL will now prompt the end-user for the
    drive they wish Starware CD-ROM Sampler to be installed onto.
*/
//@BackgroundMode(1,0,0)


@DlgCtrlSize(0,8,15,15,27)
@GetOutDrive @SampleDrive @Prompt = "Enter target drive"
@Suppress(0,17) // Suppress floppies & CD-ROM drives
Please select the drive where you wish the Starware
CD-ROM Sampler to be installed on your machine.  Any
available drive can be used assuming you have
access rights to the drive you select, and
there is approximately 930K available for installation.
@EndOutDrive

/*
    INSTALL will now prompt the end-user for the
    directory they wish Starware CD-ROM Sampler
    to be installed into.
*/

NEWDIR:
//@BackgroundMode(3,@Blue,@Black)

@DlgCtrlSize(0,7,0,8,35)
@GetSubdir @SampleDirectory @Prompt = "Enter target directory"
Please select the directory
you wish Starware CD-ROM Sampler to be installed under.

@EndSubdir
@EndIf


@If ('Q' [= @Group)
QTWNEWDRIVE:  // Goto label for reselecting drive
/*
    wINSTALL will now prompt the end-user for the
    drive they wish Quicktime 1.1 For Windows  to
    be installed onto.
*/
//@BackgroundMode(3,@Blue,@Black)


@DlgCtrlSize(0,10,15,18,27)
@GetOutDrive @QTWDrive @Prompt = "Enter target drive"
@Suppress(0,17) // Suppress floppies & CD-ROM drives
Please select the drive where you wish the Quicktime
for Windows 1.1 to be installed on your machine.
Quicktime must be installed properly for the Starware
CD-ROM Sampler to operate correctly.  Any available
drive can be used assuming you have access rights to
the drive you select, and there is approximately 1.42
Megabytes available for installation.
@EndOutDrive


/*
    INSTALL will now prompt the end-user for the
    directory they wish Quicktime to be installed
    into.
*/

QTWNEWDIR:
//@BackgroundMode(3,@Blue,@Black)


@DlgCtrlSize(0,9,0,10,35)
@GetSubdir @QTWDirectory @Prompt = "Enter target directory"
Please select the directory you wish
Quicktime for Windows 1.1 to be installed under.

@EndSubdir

@EndIf


/*  The following section demonstrates three constructs in wINSTALL.  The
    @If block, the @GoTo command, and the 'Membership' concept.  @If blocks
    can be used virtually anywhere in wINSTALL and can control many actions
    taken during the installation process.  @Goto commands can be used to
    alter the general flow of execution in the script file.  This can be
    handy in making script files that are flexible.  The 'Membership' concept
    is used for determination of GROUPS and OPTIONS that may or may not have
    been chosen during the installation.  Below for example, the condition
    inside the @If block, checks to see whether '100 is a member' of the
    @Option variable.  When a particular OPTION or GROUP is selected, a
    flag is set in the @Option or @Group variable for that specific
    OPTION number or GROUP letter.  In this way, you can test to see
    whether specific OPTIONS or GROUPS have been set.
*/


@If ('S' [= @Group) @samp = 930 @Else @samp = 0 @EndIf //if group not selected zero out
@If ('Q' [= @Group) @qtw = 1408  @Else @qtw =  0 @EndIf //if group not selected zero out


@TSIZE = @Eval((@samp+@qtw))   // add selected options' size requirements

// if total size > free space, then display
// blue background and set default to loop back and select again.

@If(@TSIZE*1024 > @DiskFree(@QTWDrive))
//@BackgroundMode(3,@Blue,@Black)
    @Display
        The drive you have selected does not have
        enough free space available.

    @Pause
    @EndDisplay
    @GOTO NEWDRIVE
@EndIf


//@BackgroundMode(3,@Blue,@Black)
@SetOption(1600) @ClearOption(1700)


@DlgCtrlSize(0,13,12,17,40)
@GetOption @Prompt = "Selected files summary"
You have selected to install the following options.
        @If ('S' [= @Group) Starware CD-ROM Sampler  @samp K @Else Starware CD-ROM Sampler WILL NOT BE INSTALLED @EndIf
        @If ('Q' [= @Group) Quicktime for Windows    @qtw K @Else Quicktime for Windows    WILL NOT BE INSTALLED @EndIf

           The selected files will require a total of:        @TSIZE K bytes.
           The drive currently selected for installation has: @Eval(@DiskFree(@OutDrive)/1K) K free.


 You may:
@Option 1600 = "CONTINUE"
@Option 1700 = "RESELECT OPTIONS"
@EndOption


@If(1700 [= @Option) @GOTO Loop @EndIf
@If('S' [= @Group)
    @Display
    @Cls
    This program will create a file called Starware.INI in @SampleDrive:@SampleDirectory.
    This file looks like:

    [Starware]
    CDDRIVE = X

    Where X should be your CD-ROM's drive letter.
    @Pause
    @Enddisplay
@EndIf

/*
    The @DefineDisk blocks actually do the copying of the files, from the
    floppy disk to the hard disk of the end-users particular choice.
*/

@DefineDisk
    @Label = "Starware CD-ROM Sampler"

/*
    The following files are not in a library and are always installed.
*/
/*              @File  README.txt   @OUT *.*                    */


@File pcsample\threed.vbx       @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 64544
@File pcsample\mkTools.vbx      @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 38912
@File pcsample\QTMovie.vbx      @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 28064
@File pcsample\Grid.vbx         @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 45136
@File pcsample\anibuton.vbx     @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 99888
@File pcsample\cmdialog.vbx     @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 18688
@File pcsample\msmasked.vbx     @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 30288
@File pcsample\picclip.vbx      @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 15840
@File pcsample\VBRUN300.DLL     @OUT @WindowsDrive:\@WindowsDir\*.* @ASKOVERWRITE @Group S @Size 300000
@File pcsample\bitmaps\splash.bmp @OUT @SampleDrive:\@SampleDirectory\*.* @Group S @Size 78778
@File pcsample\bitmaps\BOSS.bmp @OUT @SampleDrive:\@SampleDirectory\*.* @Group S @Size 78778
@File pcsample\DEMO.exe @OUT @SampleDrive:\@SampleDirectory\*.* @Group S @Size 216264
@File qtw\mciqtenu.dll  @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 3872
@File qtw\playenu.dll           @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 16592
@File qtw\qthndlr.dll           @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 8272
@File qtw\qtim.dll              @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 214976
@File qtw\qtimcmgr.dll  @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 13712
@File qtw\qtole.dll             @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 72560
@File qtw\qtvhdw.dll            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 15408
@File qtw\viewenu.dll           @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 17408
@File qtw\mciqtw.drv            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 40400
@File qtw\qtnotify.exe          @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 4080
@File qtw\navg.qtc              @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 22912
@File qtw\qcmc.qtc              @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 108400
@File qtw\qtcvid.qtc            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 181968
@File qtw\qtmsvc.qtc            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 7024
@File qtw\qtraw.qtc             @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 6992
@File qtw\qtrle.qtc             @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 92544
@File qtw\qtrpza.qtc            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 200368
@File qtw\qtrt21.qtc            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 58544
@File qtw\qtsmc.qtc             @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 164480
@File qtw\qtyvu9.qtc            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 7376
@file qtw\player.exe            @OUT @QTWDrive:\@QTWDirectory\*.* @OVERWRITE @Group Q @Size 58032
@EndDisk


//
//      The following lines will be placed into any pre-existing AUTOEXEC.BAT
//      file on the boot disk in the boot drive.  If no AUTOEXEC.BAT file
//      already exists, then one will be created.
//
//      Each of the two AUTOEXEC.BAT related commands, @Path and @Verbatim,
//      is aware of the structure of an AUTOEXEC.BAT file.
//
//      The @Path command examines each node of any existing PATH= commands
//      (or its synonym SET PATH=) and places each of the nodes specified
//      in the @Path command of the INSTALL.DAT file only if the node
//      does not already exist on the PATH= search list of the AUTOEXEC.BAT
//      file.
//
//      The @Verbatim command instructs INSTALL to place the quoted string
//      into the AUTOEXEC.BAT file, if the string is not already there.
//
@If ('Q' [= @Group)
    @SetAutoexec
        @ASKOverwrite
        @Path = "@QTWDrive:\\@QTWDirectory;"
    @EndAutoexec
@EndIf //if group not selected zero out
@Finish
@If(@BackgroundMode(1,0,0))@EndIf
@Cls
/*
    The following command is used to create the wINSTALL group and
    add the wINSTALL item to the Windows Program Manager.
*/
@If ('S' [= @Group)
    @SetINI("Starware", "CDDRIVE", @CDLetter, "@SampleDrive:@SampleDirectory\\Starware.ini")
//      @BackgroundMode(3,@Blue,@Black)

    // @SetOption(1001)

@EndIf

@If ('S' [= @Group)
    @if ('Q' [= @Group)
        @ProgramManager("[CreateGroup(Starware)][AddItem(@SampleDrive:\\@SampleDirectory\\demo.exe, Starware CD-ROM Sampler)][AddItem(@QTWDrive:\\@QTWDirectory\\player.exe, QT Player)][AddItem(@CDLetter:\\pcsample\\Readme.wri, Readme.wri)][AddItem(@CDLetter:\\pcsample\\verify.wri, BBS Verification Form)][AddItem(@CDLetter:\\pcsample\\BBSQ_A.wri, BBS Questions & Answers)][ShowGroup(Starware, 1)]"))
    @Else
        @ProgramManager("[CreateGroup(Starware)][AddItem(@SampleDrive:\\@SampleDirectory\\demo.exe, Starware CD-ROM Sampler)][AddItem(@CDLetter:\\pcsample\\Readme.wri, Readme.wri)][AddItem(@CDLetter:\\pcsample\\verify.wri, BBS Verification Form)][AddItem(@CDLetter:\\pcsample\\BBSQ_A.wri, BBS Questions & Answers)][ShowGroup(Starware, 1)]"))
    @EndIf
@Else
        @ProgramManager("[CreateGroup(Starware )][AddItem(@QTWDrive:\\@QTWDirectory\\player.exe, QT Player)][ShowGroup(Starware, 1)]"))
@EndIf
@Cls @Name is finished installing.  Thank you for your purchase.
@If('Q' [= @Group)
You must reboot your computer for Quicktime for Windows to work.
@EndIf
@ChDrive (@OutDrive)
@ChDir ("@SubDir")
@Pause
@Exit
@If(@BackgroundMode(1,0,0))
@EndIf
@EndFinish
// end-of-file